0010 USE UNIGRAPHICS
0020 USE MANDELSTEP_COMAL // Prøv også MANDELSTEP_C og MANDELSTEP_ASM
0030
0040 page
0050 tid:=timer
0060 reel_min:=-2.2; reel_max:=1.2
0070 im_min:=-1.4; im_max:=1.4
0080 max_step:=35
0090 setmax(max_step)
0100 graphicscreen(0)
0110 clear
0120 xmax:=width; ymax:=height; farveantal:=2^depth-1
0130 IF xmax>640 THEN xmax:=640
0140 y_ratio:=(im_max-im_min)/ymax
0150 x_ratio:=(reel_max-reel_min)/xmax
0160 FOR punkt_y:=0 TO ymax-1 DO
0170   im_c:=punkt_y*y_ratio+im_min
0180   FOR punkt_x:=0 TO xmax-1 DO
0190     reel_c:=punkt_x*x_ratio+reel_min
0200     antal_step:=calcstep(reel_c,im_c)
0210     IF antal_step>=max_step THEN
0220       pencolor(2);plot(punkt_x,punkt_y)
0230     ELSE
0240       c:=3+antal_step MOD farveantal
0250       IF c<>0 THEN pencolor(c);plot(punkt_x,punkt_y)
0260       pencolor(3+antal_step)
0270     ENDIF
0280   ENDFOR punkt_x
0290 ENDFOR punkt_y
0300 tid:=timer-tid
0310 WAIT
