
; Script file to install reqtools.library 38 on Kickstart 1.2/1.3

FailAt 20

Version >NIL: exec.library 37
If NOT WARN
	Echo "*nYour Amiga has Kickstart 2.0 or higher in ROM."
	Echo "Please run the install script for Workbench 2.0 or"
	Echo "one of the install scripts for Workbench 2.1 or higher."
	Skip END
EndIf

Echo "*nreqtools.library Installation Script*n"
Version >NIL: LIBS:reqtools.library
If NOT ERROR
	Echo "Version of reqtools.library already installed:"
	Version LIBS:reqtools.library
	Echo ""
EndIf

Ask "Install Kickstart 1.2/1.3 version of reqtools.library (38.358) ?"
If NOT WARN
	Skip Aborted
EndIf

Copy /libs13/reqtools.library LIBS:reqtools.library
Echo "*nreqtools.library copied to your Libs: directory."

Lab INSTALLED

Echo "Installation complete.*n"
Skip END

Lab ABORTED

Echo "*nInstallation aborted!*n"

Lab END

Wait 5
EndCLI >NIL:
